MobProg Examples from Aladon
Примеры MobProgs из мира Аладона

#MOBILES
#1001
князь prince~
князь~
Князь Триграда грозно смотрит на тебя.
~
Высокий красивый бородатый мужик в красном плаще.
~
.............
M GREET 1001 100~ - при входе кого-то 100% сработает п.1001
M ACT 1002 кланяется тебе~ - срабатывает п.1002 если кто-то кланяется князю
M KILL 1006 100~ - если кто-то начнет убивать князя 100% сработает п.1006

.....

#1002
пес fido dog~
пес:пса:псу:пса:псом:псе~
Бродячий пес роется в отбросах.
~
Дворняга совершенно непонятной масти и расцветки.
Он весь в грязи и ужасно воняет.
~
......
M RANDOM 1092 10~ - в 10% при обновлении моба выполнится п.1092

.....

#1011
guard стражник~
стражник~
Стражник охраняет ворота.
~
Он сильный и большой. С ним лучше не связываться, пожалуй.
~
.....
M GREET 1011 100~ - в 100% если кто-то войдет в комнату выполнится п.1011

.....

#1026
дворник janitor~
дворник~
Бородатый дворник метет улицу.
~
Он занят своим делом - не мешай ему.
~
.....
M ENTRY 1028 50~ - в 50% если дворник войдет в комнату выполнится п.1028
M GREET 1028 50~ - аналогично - но если кто-то войдет в комнату с дворником
M ACT 1027 бросает~ - если кто-то что-то бросит выполнится п.1027
M RANDOM 1026 10~ - в 10% выполнится п.1026

.....

#6003
тролль стражник troll guard~
стражник~
Большой тролль-стражник пялит на тебя свои глазищи.
~
Он поставлен тут охранять вход в Пещеру. Большой
и толстый, но тупоооой!
~
.....
M GREET 6003 100~ - в 100% если кто-то войдет в комнату выполнится п.6003
M DELAY 6001 100~ - в 100% выполнится п.6001, когда у моба закончится период ожидания

.....

#6101
абрек abrek~
абрек~
Чернобородый абрек хмуро смотрит на тебя.
~
Черноволосый смуглый горбоносый мужчина. Он настроен
решительно.
~
.....
M GREET 6101 100~ - в 100% выполнится п.6101, когда кто-то войдет в комнату

.....

#MOBPROGS
#1001
if level $n < 15
and level $n >= 5
 say Смерд ! Не оскверняй мой взор своим присутсвием !
 if isnpc $n
   mob force $n east
 endif
 break
endif
eyebrow
 if sex $n < 2
   say Что привело сюда ясновельможного пана ?
 else
   say Что привело сюда ясновельможную пани ?
 endif
~
#1002
say Ладно уж, иди !
~
#1006
mob echo {W$I восклицает: {CУмри, смерд поганый !{x
mob force bodyguard rescue prince
~
#1011
if isimmort $n
  tip $n
  break
endif
if race $n reptile
  yell К оружию! Змеи идут!
  mob kill $n
  break
endif
if race $n elf
  say Эй, эльф! У нас тут вас не особо жалуют!
  spit
  break
endif
if race $n dwarf
or race $n orc
or race $n troll
  say Ну куда ты, земляная рожа, прешься ?
  grin
  break
endif
if race $n hobbit
  say Проходи, половинчик!
  break
endif
~
#1026
if rand 50
 mob echo $I бормочет: Свиньи... Насвинячат, набросают, а мне убирай !
else
 mob echo $I бормочет: Ходют тут всякие, мусорют...
endif
~
#1027
if rand 5
 yell Ты мне, сволочь, получишь за это !
 mob kill $n
endif
~
#1028
if vnum $n == 1002
 say А ну пшел вон, пес смердячий !
 emote замахивается метлой на пса.
 mob force $n emote огрызается.
endif
~
#1092
if rand 50
  bark $n
else
  mob echoat $n $I окропляет твои ноги мочой.
  mob echoaround $n $I окропляет ноги $n2 мочой.
endif
~
#6001
if hastarget $i
and istarget $q
  growl
  say Ты не понимаешь слов ??!
  yell Хреееееяяяк!!
  mpkill $q
else
  mob forget
endif
~
#6003
if isimmort $n
  bow $n
  break
endif
if race $n dwarf
yell О! Гномы пожаловали! Будет обед!!!
  mob kill $n
  break
endif
if race $n elf
yell Эльфы идут! Мочи их!!!
  mob kill $n
  break
endif
if race $n human
or race $n hobbit
or race $n reptile
or race $n insect
  mpecho {W$I произносит: {CНу чего пришли? Проваливайте!{x
  emote замахивается топором.
  mob remember $n
  mob delay 5
  break
endif
~
#6101
if rand 50
  say Слюшай, дарагой! Ты сюда не хады! Дамой хады!
else
  say Дарагой! Ти чужой нам - ухады!
endif
~
#0